# Maintainer: nimbt <niko@n1kt.ru>
# Для разработки: nimble build && sudo cp nbt nimbt-daemon /usr/bin/
pkgname=nimbt
pkgver=0.1.0
pkgrel=2
pkgdesc="Lightweight Bluetooth manager for Linux (daemon + CLI)"
arch=('x86_64' 'aarch64')
url="https://git.n1kt.ru/Niko/nim-bt"
license=('MIT')
depends=('dbus' 'glibc')
makedepends=('nim' 'nimble')
source=("$pkgname-$pkgver.tar.gz::https://git.n1kt.ru/Niko/nim-bt/archive/v$pkgver.tar.gz")
sha256sums=('SKIP')

_repodir=nim-bt

build() {
  cd "$srcdir/$_repodir"
  nimble install -y --depsOnly --nimbleDir:"$srcdir/nimble" 2>/dev/null || true
  export NIMBLE_DIR="$srcdir/nimble"
  nim c \
    --path:"$NIMBLE_DIR/pkgs2" \
    --mm:orc -d:release --opt:speed --hints:off \
    -o:build/nbt src/nbt.nim
  nim c \
    --path:"$NIMBLE_DIR/pkgs2" \
    --mm:orc -d:release --opt:speed --hints:off \
    -o:build/nimbt-daemon src/nimbt_daemon.nim
}

package() {
  cd "$srcdir/$_repodir"
  install -Dm755 build/nbt "$pkgdir/usr/bin/nbt"
  install -Dm755 build/nimbt-daemon "$pkgdir/usr/bin/nimbt-daemon"
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  install -Dm644 nimbt-daemon.service "$pkgdir/usr/lib/systemd/user/nimbt-daemon.service"
}
